Aufschreibregeln für Funktionen
Einführung in die Programmierung

Die Funktion profit:

;; berechnet den Profit aus der Differenz zwischen
;; Einnahmen und Kosten bei gegebenem Kartenpreis
(define profit
  (lambda [kartenpreis]
    nil))

Das Symbol nil steht hier als Platzhalter für den noch zu bestimmenden Funktionsrumpf.

Die Berechnung der Einnahmen:

;; berechnet die Einnahmen aus dem Produkt von 
;; Besucherzahl und Kartenpreis
(define einnahmen
  (lambda [kartenpreis]
    nil))

Die Berechnung der Kosten:

;; berechnet die entstehenden Kosten bei gegebenem
;; Kartenpreis aus Fixkosten und variablen Kosten
(define kosten
  (lambda [kartenpreis]
    nil))

Die Berechnung der Besucherzahl:

;; berechnet die Besucherzahl bei gegebenem
;; Kartenpreis nach empirisch ermittelter Formel
(define besucherzahl
  (lambda [kartenpreis]
    nil))

In diesem Schritt versuchen wir Beispielanwendungen zu finden; beginnen wir mit der Funktion besucherzahl.

Aus der Problembeschreibung lassen sich direkt die beiden folgende Beispiele ableiten:

• (besucherzahl 500) = 120
• (besucherzahl 490) = 135

Für weitere Beispiele müssten Annahmen getroffen werden, die die Problembeschreibung nicht direkt hergibt. So sind die beiden folgenden Beispiele nur dann korrekt, wenn aus den Beispielen der Problembeschreibung eine linearer Zusammenhang zwischen dem Kartenpreis und der Besucherzahl angenommen wird:

• (besucherzahl 510) = 105
• (besucherzahl 400) = 270

Ob diese Annahme sinnvoll ist, müsste letztendlich der Auftraggeber entscheiden. Für die folgenden Betrachtungen legen wir diese Annahme zugrunde.

Ein linearer Zusammenhang ergäbe die folgende Geradengleichung: \[besucherzahl(kartenpreis) = 120 + \frac{15}{10}\cdot (500 - kartenpreis)\]

Beispielanwendungen für die Funkton besucherzahl:

;; berechnet die Besucherzahl bei gegebenem
;; Kartenpreis nach empirisch ermittelter Formel
(define besucherzahl
  (lambda [kartenpreis]
    nil))

;; Beispielanwendungen
(= (besucherzahl 500) 120)
(= (besucherzahl 490) 135)
(= (besucherzahl 510) 105)
(= (besucherzahl 400) 270)

Beispielanwendungen für die Funkton kosten:

;; berechnet die entstehenden Kosten bei gegebenem
;; Kartenpreis aus Fixkosten und variablen Kosten
(define kosten
  (lambda [kartenpreis]
    nil))

;; Beispielanwendungen
(= (kosten 500) 18600)
(= (kosten 400) 19350)

Beispielanwendungen für die Funkton einnahmen:

;; berechnet die Einnahmen aus dem Produkt von 
;; Besucherzahl und Kartenpreis
(define einnahmen
  (lambda [kartenpreis]
    nil))

;; Beispielanwendungen
(= (einnahmen 500) 60000)
(= (einnahmen 400) 108000)

Beispielanwendungen für die Funkton profit:

;; berechnet den Profit aus der Differenz zwischen
;; Einnahmen und Kosten bei gegebenem Kartenpreis
(define profit
  (lambda [kartenpreis]
    nil))

;; Beispielanwendungen
(= (profit 500) 41400)
(= (profit 400) 88650)

Beginnen wir wieder mit der Funktion besucherzahl. Der für die Ermittlung der Beispielanwendungen zugrunde gelegte lineare Zusammenhang zwischen Besucherzahl und Kartenpreis wird direkt in die Berechnungsvorschrift für die Funktion genutzt:

;; berechnet die Besucherzahl bei gegebenem
;; Kartenpreis nach empirisch ermittelter Formel
(define besucherzahl
  (lambda [kartenpreis]
    (+ 120 (* (/ 15 10) (- 500 kartenpreis)))))

;; Beispielanwendungen
(= (besucherzahl 500) 120)
(= (besucherzahl 490) 135)
(= (besucherzahl 510) 105)
(= (besucherzahl 400) 270)

Die Berechnungsvorschrift der Funktion kosten ergibt sich aus dem oben formulierten Zusammenhang (Die Kosten sind die Summe aus den Fixkosten (18000 Währungseinheiten) und dem Produkt aus Besucheranzahl und den Kosten pro Besucher (5 Währungseinheiten).):

;; berechnet die entstehenden Kosten bei gegebenem
;; Kartenpreis aus Fixkosten und variablen Kosten
(define kosten
  (lambda [kartenpreis]
    (+ 18000 (* 5 (besucherzahl kartenpreis)))))

;; Beispielanwendungen
(= (kosten 500) 18600)
(= (kosten 400) 19350)

Man beachte, dass die Funktion kosten die Funktion besucherzahl als Hilfsfunktion benutzt.

Die Berechnungsvorschrift für die Funktion einnahmen als Produkt aus Besucherzahl und Kartenpreis:

;; berechnet die Einnahmen aus dem Produkt von 
;; Besucherzahl und Kartenpreis
(define einnahmen
  (lambda [kartenpreis]
    (* (besucherzahl kartenpreis) kartenpreis)))

;; Beispielanwendungen
(= (einnahmen 500) 60000)
(= (einnahmen 400) 108000)

Man beachte auch hier die Verwendung von besucherzahl als Hilfsfunktion.

Schließlich werden in der Berechnungsvorschrift für profit die Funktionen einnahmen und kosten benutzt:

;; berechnet den Profit aus der Differenz zwischen
;; Einnahmen und Kosten bei gegebenem Kartenpreis
(define profit
  (lambda [kartenpreis]
    (- (einnahmen kartenpreis)
       (kosten kartenpreis))))

;; Beispielanwendungen
(= (profit 500) 41400)
(= (profit 400) 88650)

Regel 4 (Hilfsfunktionen):

Definiere für jeden Zusammenhang zwischen Größen, die sich aus der Problembeschreibung ergeben, eine Funktion.

Prozedurale Abstraktion

• Die Funktion profit, wie sie oben definiert wurde, zerlegt das Problem der Berechnung des Profit in zwei Teilprobleme, nämlich auf die Berechnung der Einnahmen und der Kosten.
• Die Funktionen einnahmen und kosten liefern eine Abstraktion von den Details ihrer Berechnungen. Auch wenn sich diese Details verändern, kann die Funktion profit unverändert bleiben.

Man könnte die Funktion profit auch ohne die Verwendung von Hilfsfunktionen aufschreiben:

(define profit
  (lambda [kartenpreis]
    (- (* (+ 120 (* (/ 15 10 )
                    (- 500 kartenpreis)))
          kartenpreis)
       (+ 18000
          (* 5 (+ 120
                  (* (/ 15 10 )
                     (- 500 kartenpreis))))))))

Diese Funktion berechnet das Gleiche wie die Variante mit Hilfsfunktionen, ist aber völlig unlesbar. Sollte in dieser Funktion der Zusammenhang zwischen Kartenpreis und Besucherzahl geändert werden müssen, wäre dies eine nur schwer lösbare Aufgabe.

Die Lesbarkeit der Funktion profit (in beiden Varianten) und ihrer Hilfsfunktionen ist auch dadurch eingeschränkt, dass in den Berechnungsvorschriften eine Reihe von Zahlen auftreten, deren Bedeutung nicht unmittelbar einleuchtend sein muss.

Regel 5 Konstantendefinitionen:

Ersetze jede Konstante, deren Bedeutung sich nicht aus dem Kontext ergibt, durch einen sprechenden Variablennamen.

Zum Beispiel für die Funktion profit und ihre Hilfsfunktionen:

(define fixkosten 18000)
(define kosten-pro-besucher 5)
(define basis-besucherzahl 120)
(define besucher-preis-faktor (/ 15 10))
(define preis-fuer-basis-besucherzahl 500)        

(Das vollständige Programm profit (kino.rkt) steht in moodle zur Verfügung.)

Gegenbeispiel: In der Formel zur Berechnung der Dreiecksfläche

(/ (* grundseite hoehe) 2)

nicht die Konstante 2 durch eine eine benannte Konstante zwei ersetzen.

(s. Aufgaben 7 und 8)